Safe Ubound And Lbound

imacul8

Aug 20 2006, 02:35 AM

Ever wanted to use LBound and UBound to get arrays boundaries without jumping over error message when the array is empty? These functions will replace the ordinary LBound and UBound procedures so you don’t need to worry about errors. I've also included a way to get the dimensions of an array. Just paste the following code into a module, and the problem is solved.

Inputs: SafeUBound and SafeLBound: [Address to the array], [What dimension you want to obtain]
ArrayDims: [Address To the array]
Returns: As expected from the ordinary functions, except that they will return -1 when the array is empty.
Assumes: You obtain the address to an array by passing it to the VarPtrArray API call. So if you want to get the boundaries of an array called aTmp, you need to call the functions like this:
lLowBound = SafeLBound(VarPtrArray(aTmp))
lHighBound = SafeUBound(VarPtrArray(aTmp))
lDimensions = ArrayDims(VarPtrArray(aTmp))
When dealing With String arrays that isn't allocated at design time, you *must* add the value 4 To the lpArray-paramenter:
lLowBound = SafeLBound(VarPtrArray(aString) + 4)

Side Effects: Since the return value is minus when the array is empty it's a big chance you will get problems with minus dimensioned arrays, but who use them anyway?

CODE

Option Explicit

Declare Function VarPtrArray Lib "msvbvm50.dll" Alias "VarPtr" (Ptr() As Any) As Long

Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)

Public Function SafeUBound(ByVal lpArray As Long, Optional Dimension As Long = 1) As Long
    Dim lAddress&, cElements&, lLbound&, cDims%

    If Dimension < 1 Then
        SafeUBound = -1
        Exit Function
    End If
    CopyMemory lAddress, ByVal lpArray, 4

    If lAddress = 0 Then
        ' The array isn't initilized
        SafeUBound = -1
        Exit Function
    End If
    ' Calculate the dimensions
    CopyMemory cDims, ByVal lAddress, 2
    Dimension = cDims - Dimension + 1
    ' Obtain the needed data
    CopyMemory cElements, ByVal (lAddress + 16 + ((Dimension - 1) * 8)), 4
    CopyMemory lLbound, ByVal (lAddress + 20 + ((Dimension - 1) * 8)), 4
    SafeUBound = cElements + lLbound - 1
End Function

Public Function SafeLBound(ByVal lpArray As Long, Optional Dimension As Long = 1) As Long
    Dim lAddress&, cElements&, lLbound&, cDims%

    If Dimension < 1 Then
        SafeLBound = -1
        Exit Function
    End If
    CopyMemory lAddress, ByVal lpArray, 4

    If lAddress = 0 Then
        ' The array isn't initilized
        SafeLBound = -1
        Exit Function
    End If
    ' Calculate the dimensions
    CopyMemory cDims, ByVal lAddress, 2
    Dimension = cDims - Dimension + 1
    ' Obtain the needed data
    CopyMemory lLbound, ByVal (lAddress + 20 + ((Dimension - 1) * 8)), 4
    SafeLBound = lLbound
End Function

Public Function ArrayDims(ByVal lpArray As Long) As Integer
    Dim lAddress As Long
    CopyMemory lAddress, ByVal lpArray, 4

    If lAddress = 0 Then
        ' The array isn't initilized
        ArrayDims = -1
        Exit Function
    End If
    CopyMemory ArrayDims, ByVal lAddress, 2
End Function

Hope this solves any problems u have of getting errors with empty arrays.

Plagiarism is never tolerated in Trap17 forum. If you're going to copy the program code, do not leave out the copyright statement! This code is copyrighted. Source http://www.planetsourcecode.com/vb/scripts...&lngWId=-10

Galahad

Aug 21 2006, 12:44 PM

I was just about to write it was copied from PSC, but BuffaloHELP got here before me

Anyways, this code is good, since it uses Windows API, but this same code can be written in pure VB, with just a little error handling

Here it is:

CODE

Private Function SafeLBound() As Long
On Local Error GoTo SafeLBound_Err

SafeLBound = LBound(Niz)

SafeLBound_Exit:
Exit Function

SafeLBound_Err:
If Err.Number = 9 Then SafeLBound = -1
Resume SafeLBound_Exit
End Function

Private Function SafeUBound() As Long
On Local Error GoTo SafeUBound_Err

SafeUBound = UBound(Niz)

SafeUBound_Exit:
Exit Function

SafeUBound_Err:
If Err.Number = 9 Then SafeUBound = -1
Resume SafeUBound_Exit
End Function

This code will work only with project-level, or form/module-level arrays, since building a function that checks arrays, would require a function for each data-type in Visual Basic, because useing arrays as function or procedure parameters, requires passinge them by refference (ByRef), so you can for example declare input parameter as array of variants, and pass array of strings... That would cause another run-time error

ADD REPLY / Got an Opinion!	a humble request :-)	RAPID SEARCH!	Free Hosting	[X]
Express your Opinions, Thoughts or Contribute your information that might help someone here. Ask your Doubts & Queries to get answers.. "Together, We enlight each other!"	Register FREE for AD-FREE forum, Create your own topics, Ask Questions, track topics, setup subscriptions & notifications and Get a Free Website w/ Email and FTP.		500MB Space No Ads, CPanel, FTP, PHP, MySQL, EMails - 100% FREE